模組 Either

module Either: sig .. end

Either 類型。

Either 是最簡單且最通用的總和/變體類型：類型為 ('a, 'b) Either.t 的值可以是 Left (v : 'a) 或 Right (v : 'b)。

在通用函式的 API 中，這是一個自然的選擇，這些函式的值可能屬於兩種不同的情況，而且類型可能不同，而無需為每種情況指定特定的含義。

例如

List.partition_map:
    ('a -> ('b, 'c) Either.t) -> 'a list -> 'b list * 'c list

如果您正在尋找一種參數化類型，其中一個選項表示成功，另一個選項表示失敗，則應使用更具體的類型 Result.t。

type ('a, 'b) t =
| Left of 'a
| Right of 'b

類型為 ('a, 'b) Either.t 的值包含 'a 類型的值或 'b 類型的值

val left : 'a -> ('a, 'b) t

left v 是 Left v。

val right : 'b -> ('a, 'b) t

right v 是 Right v。

val is_left : ('a, 'b) t -> bool

is_left (Left v) 為 true，is_left (Right v) 為 false。

val is_right : ('a, 'b) t -> bool

is_right (Left v) 為 false，is_right (Right v) 為 true。

val find_left : ('a, 'b) t -> 'a option

find_left (Left v) 為 Some v，find_left (Right _) 為 None

val find_right : ('a, 'b) t -> 'b option

find_right (Right v) 為 Some v，find_right (Left _) 為 None

val map_left : ('a1 -> 'a2) -> ('a1, 'b) t -> ('a2, 'b) t

如果 e 是 Left v，則 map_left f e 為 Left (f v)，如果 e 是 Right _，則為 e。

val map_right : ('b1 -> 'b2) -> ('a, 'b1) t -> ('a, 'b2) t

如果 e 是 Right v，則 map_right f e 為 Right (f v)，如果 e 是 Left _，則為 e。

val map : left:('a1 -> 'a2) ->
       right:('b1 -> 'b2) -> ('a1, 'b1) t -> ('a2, 'b2) t

map ~left ~right (Left v) 為 Left (left v)，map ~left ~right (Right v) 為 Right (right v)。

val fold : left:('a -> 'c) -> right:('b -> 'c) -> ('a, 'b) t -> 'c

fold ~left ~right (Left v) 為 left v，fold ~left ~right (Right v) 為 right v。

val iter : left:('a -> unit) -> right:('b -> unit) -> ('a, 'b) t -> unit

iter ~left ~right (Left v) 為 left v，iter ~left ~right (Right v) 為 right v。

val for_all : left:('a -> bool) -> right:('b -> bool) -> ('a, 'b) t -> bool

for_all ~left ~right (Left v) 為 left v，for_all ~left ~right (Right v) 為 right v。

val equal : left:('a -> 'a -> bool) ->
       right:('b -> 'b -> bool) -> ('a, 'b) t -> ('a, 'b) t -> bool

equal ~left ~right e0 e1 使用 left 和 right 分別比較 Left _ 和 Right _ 包裹的值，來測試 e0 和 e1 的相等性。

val compare : left:('a -> 'a -> int) ->
       right:('b -> 'b -> int) -> ('a, 'b) t -> ('a, 'b) t -> int

compare ~left ~right e0 e1 使用 left 和 right 分別比較 Left _  和 Right _ 包裹的值，來完全排序 e0 和 e1。Left _ 的值小於 Right _ 的值。